[Wojciech]

I need simple drop down select control: just some fixed options to chose, without any advanced model.

I can’t see in v-play control set anything suitable, I tried to use ComboBox from Qt, but I got message that the type doesn’t exists.

What should I use?

 

[GüntherFelgo Team]

Hi!

You can use the Qt ComboBox also in Felgo Projects. For a usage example, please have a look at the Component Showcase demo. The ComboBox is shown on the Controls page and also on several other pages for choosing different options/examples.

The demo also already adds a custom style to use density-independent sizes, here’s the quick reference implementation of the showcase:

import Felgo 3.0
import QtQuick 2.5
import QtQuick.Controls 2.0 as Quick2

Quick2.ComboBox {
  id: comboBox
  implicitWidth: dp(90) + 20
  implicitHeight: dp(24) + topPadding + bottomPadding
  padding: dp(12)
  
  // model - options of combobox
  model: ["First", "Second", "Third"]

  // overwrite style for density independent sizes
  delegate: Quick2.ItemDelegate {
    width: comboBox.implicitWidth
    height: comboBox.implicitHeight
    padding: dp(12)
    contentItem: AppText {
      text: modelData
      color: highlighted ? Theme.tintColor : Theme.textColor
      wrapMode: Text.NoWrap
    }
    highlighted: comboBox.highlightedIndex == index
  }

  contentItem: AppText {
    width: comboBox.width - comboBox.indicator.width - comboBox.spacing
    text: comboBox.displayText
    wrapMode: Text.NoWrap
  }
}

 

Best,
Günther from Felgo