[David]

Hi,

I want to hide the device status, when the Picture Viewer is showing. How can I do this?

Greetings!

[GüntherFelgo Team]

Hi David!

The status bar can be configured with the Theme.colors.statusBarStyle property:

import Felgo 3.0
import QtQuick 2.5

App {
  id: app

  NavigationStack {
    splitView: false

    Page {
      title: "Status Bar Test"

      Column {
        anchors.centerIn: parent

        AppButton {
          text: "Show Status Bar"
          onClicked: Theme.colors.statusBarStyle = Theme.colors.statusBarStyleBlack
        }

        AppButton {
          text: "Hide Status Bar"
          onClicked: Theme.colors.statusBarStyle = Theme.colors.statusBarStyleHidden
        }

      }
    }
  }
}

Best,
Günther

• This reply was modified 7 years, 5 months ago by  GT.

[David]

Ah,thanks, it works! But I have another problem now. If the PictureViewer is open, the statusbar is hidden, but how can I make the statusbar visible, when the PictureViewer is closed?

[GüntherFelgo Team]

Hi David!

Good question! Had to play around a bit myself to work that one out 😉

The tricky part is how to find out when the viewer is closed. Luckily the show method returns the viewer item, which has a property isOpen that we can use:

import Felgo 3.0
import QtQuick 2.0

App {
  id: app

  // react to closing the picture viewer
  property Item viewer: null
  Connections {
    target: viewer
    onIsOpenChanged: if(!viewer.isOpen) Theme.colors.statusBarStyle = Theme.colors.statusBarStyleBlack
  }

  Page {
    // show image
    Image {
      source: "../assets/vplay-logo.png"
      anchors.centerIn: parent

      // open viewer if image clicked
      MouseArea {
        anchors.fill: parent
        onClicked: {
          viewer = PictureViewer.show(app, parent)
          Theme.colors.statusBarStyle = Theme.colors.statusBarStyleHidden
        }
      }
    }
  }
}

 

The Connections object allows to define a handler for signals of a certain target item, which is what we can use to find out when the viewer was closed. You can use this solution for now.

 

While I was researching your problem, I made some adjustments to the PictureViewer item. As from the next Felgo release you can use it like this:

import Felgo 3.0
import QtQuick 2.0

App {
  id: app

  // react to closing the picture viewer
  Connections {
    target: PictureViewer
    onClosed: Theme.colors.statusBarStyle = Theme.colors.statusBarStyleBlack
  }

  Page {
    // show image
    Image {
      source: "../assets/vplay-logo.png"
      anchors.centerIn: parent

      // open viewer if image clicked
      MouseArea {
        anchors.fill: parent
        onClicked: {
          PictureViewer.show(app, parent.source)
          Theme.colors.statusBarStyle = Theme.colors.statusBarStyleHidden
        }
      }
    }
  }
}

 

It will be possible to directly access onClosed and onOpened signals of the PictureViewer. Also, it will be possible to pass an url to the show method. (The current version expects an Image item.)

Best,
Günther

 

 

• This reply was modified 7 years, 5 months ago by  GT.