Build Native Cross-Platform Apps with the Felgo SDK.

import QtQuick 2.0
import Felgo 3.0

App {
  id: app

  onInitTheme: Theme.platform = "ios"

  Navigation {

    NavigationItem {
      title: "Main Page"
      icon: IconType.heart

      NavigationStack {
        Page {
          id: mainPage
          title: "Main"

          rightBarItem: TextButtonBarItem {
            text: "Theme"
            onClicked: Theme.platform = nextTheme()
          }

          Column {
            anchors.centerIn: parent

            AppButton {
              text: "Push Sub Page"
              flat: false
              onClicked: mainPage.navigationStack.push(subPageComponent)
            }
          }
        }
      }
    }
    NavigationItem {
      title: "Second Page"
      icon: IconType.image

      NavigationStack {
        Page {
          title: "Second"

          AppImage {
            source: "../assets/felgo-logo.png"
            anchors.centerIn: parent
          }
        }
      }
    }
  }

  function nextTheme() {
    return Theme.platform == "ios" ? "android" : Theme.platform == "android" ? "windows" : "ios"
  }

  Component {
    id: subPageComponent

    ListPage {
      title: "Sub Page"
      backgroundColor: "#f1f2f3"
      model: 100

      delegate: AppListItem {
        text: "Item " + modelData
      }
    }
  }
}

Try More Examples

You can try many more examples in your browser, or on your mobile phone with the Felgo Developer App.