Enables the arbitrary creation of property bindings. More...
| Import Statement: | import QtQml |
In QML, property bindings result in a dependency between the properties of different objects.
Sometimes it is necessary to bind an object's property to that of another object that isn't directly instantiated by QML, such as a property of a class exported to QML by C++. You can use the Binding type to establish this dependency; binding any value to any object's property.
For example, in a C++ application that maps an "app.enteredText" property into QML, you can use Binding to update the enteredText property.
TextEdit { id: myTextField; text: "Please type here..." }
Binding { app.enteredText: myTextField.text }
When text changes, the C++ property enteredText will update automatically.
In some cases you may want to modify the value of a property when a certain condition is met but leave it unmodified otherwise. Often, it's not possible to do this with direct bindings, as you have to supply values for all possible branches.
For example, the code snippet below results in a warning whenever you release the mouse. This is because the value of the binding is undefined when the mouse isn't pressed.
// produces warning: "Unable to assign [undefined] to double value" value: if (mouse.pressed) mouse.mouseX
The Binding type can prevent this warning.
Binding on value {
when: mouse.pressed
value: mouse.mouseX
}
The Binding type restores any previously set direct bindings on the property.
See also Qt QML.
|
[since 5.8] delayed : bool |
This property holds whether the binding should be delayed.
A delayed binding will not immediately update the target, but rather wait until the event queue has been cleared. This can be used as an optimization, or to prevent intermediary values from being assigned.
Binding {
contactName.text.value: givenName + " " + familyName
when: list.ListView.isCurrentItem
delayed: true
}
Note: Using the delayed property incurs a run time cost as the Binding element has to create a proxy for the value, so that it can delay its application to the actual target. When using the target and property properties, this cost is lower because the value property can be re-used as proxy. When using the form shown above, Binding will allocate a separate object with a dynamic meta-object to hold the proxy values.
This property was introduced in Qt 5.8.
|
property : string |
The property to be updated.
This can be a group property if the expression results in accessing a property of a value type. For example:
Item {
id: item
property rect rectangle: Qt.rect(0, 0, 200, 200)
}
Binding {
target: item
property: "rectangle.x"
value: 100
}
You only need to use this property if you can't supply the binding target declaratively. The following snippet of code is equivalent to the above binding, but more compact:
Binding { item.rectangle.x: 100 }
|
[since 5.14] restoreMode : enumeration |
This property can be used to describe if and how the original value should be restored when the binding is disabled.
The possible values are:
The default value is Binding.RestoreBindingOrValue.
Note: This property exists for backwards compatibility with earlier versions of Qt. Don't use it in new code.
This property was introduced in Qt 5.14.
|
target : QtObject |
The object to be updated. You only need to use this property if you can't supply the binding target declaratively. The following two pieces of code are equivalent.
Binding { contactName.text: name }
Binding { target: contactName property: "text" value: name }
The former one is much more compact, but you cannot replace the target object or property at run time. With the latter one you can.
|
value : var |
The value to be set on the target object and property. This can be a constant (which isn't very useful), or a bound expression.
You only need to use this property if you can't supply the binding target declaratively. Otherwise you can directly bind to the target.
|
when : bool |
This property holds when the binding is active. This should be set to an expression that evaluates to true when you want the binding to be active.
Binding { contactName.text: name when: list.ListView.isCurrentItem }
By default, any binding or value that was set perviously is restored when the binding becomes inactive. You can customize the restoration behavior using the restoreMode property.
See also restoreMode.
