• Home
• Felgo
• ZeroConf

ZeroConf

The ZeroConf singleton allows discovering network services via Bonjour/ZeroConf. More...

• List of all members, including inherited members

Properties

• networkServiceDiscoveryActive : bool

Signals

• networkServiceDiscovered(var serviceData)
• networkServiceDiscoveryFailed(var errorData)
• networkServiceRemoved(var serviceData)

Methods

• void startNetworkServiceDiscovery(string serviceType, string domain)
• void stopNetworkServiceDiscovery()

Detailed Description

This object is available as a singleton type from all QML components when Felgo is imported via import Felgo. It is accessible with the name ZeroConf. The ZeroConf singleton allows to discover network services in the local network via Bonjour/ZeroConf.

To start discovering services on supported devices on Android, iOS, and macOS, call startNetworkServiceDiscovery().

 ZeroConf.startNetworkServiceDiscovery("_companion_link._tcp.", "local")

After the discovery starts, networkServiceDiscoveryActive is true. Any additional calls to this method will fail until it is stopped with a call to stopNetworkServiceDiscovery(). If the discovery fails to start it emits networkServiceDiscoveryFailed().

Example Usage

The following example discovers and lists services for all found types:

 import QtQuick
 import Felgo

 App {
   id: app

   readonly property string serviceTypeAllServices: "_services._dns-sd._udp."

   readonly property bool searching: ZeroConf.networkServiceDiscoveryActive

   property var foundServices: ({})

   Component.onCompleted: ZeroConf.startNetworkServiceDiscovery(serviceTypeAllServices)

   NavigationStack {
     id: stack

     ListPage {
       title: "Service types"

       emptyText.text: "Searching for service types..."

       model: Object.values(foundServices).filter(service => !service.resolved)

       delegate: AppListItem {
         text: modelData.name
         detailText: modelData.type

         onSelected: showServiceType(modelData)
       }
     }
   }

   Component {
     id: servicesPage

     ListPage {
       title: "Services for: " + serviceType

       required property string serviceType

       emptyText.text: "Searching for services..."

       onPushed: {
         console.log("Start search for type:", serviceType)

         ZeroConf.stopNetworkServiceDiscovery()
         ZeroConf.startNetworkServiceDiscovery(serviceType)
       }

       onPopped: {
         ZeroConf.stopNetworkServiceDiscovery()
         ZeroConf.startNetworkServiceDiscovery(serviceTypeAllServices)
       }

       model: Object.values(foundServices).filter(service => service.type === serviceType)

       delegate: AppListItem {
         text: modelData.name

         detailText: "Type: %1\nDomain: %2\nHost: %3\nPort: %4\nAddresses: %5\nAttributes: %6"
         .arg(modelData.type)
         .arg(modelData.domain)
         .arg(modelData.hostName)
         .arg(modelData.port)
         .arg(JSON.stringify(modelData.addresses, null, "  "))
         .arg(JSON.stringify(modelData.attributes, null, "  "))
       }
     }
   }

   Connections {
     target: ZeroConf

     function onNetworkServiceDiscovered(serviceData) {
       console.log("Network service discovered:", JSON.stringify(serviceData, null, "  "))

       foundServices[serviceData.name] = serviceData
       foundServicesChanged()
     }

     function onNetworkServiceRemoved(serviceData) {
       console.log("Network service removed:", JSON.stringify(serviceData, null, "  "))

       delete foundServices[serviceData.name]
       foundServicesChanged()
     }

     function onNetworkServiceDiscoveryFailed(errorData) {
       console.log("Network service search failed:", JSON.stringify(errorData, null, "  "))
     }
   }

   function showServiceType(serviceModel) {
     // the service search returns the type property like "_udp.local.", containing protocol and domain
     // split it to get the protocol, and add it to the service name
     var elems = serviceModel.type.split(".")
     var serviceType = "%1.%2.".arg(serviceModel.name).arg(elems[0])

     stack.push(servicesPage, { serviceType: serviceType })
   }
 }

Integration steps

Some platforms require additional integration steps to use network service discovery.

iOS Integration

Using this method requires additional entries in your ios/Project-Info.plist file. Add the NSLocalNetworkUsageDescription with a description of how your app uses the local network. Add all service types your app uses to the array NSBonjourServices. If you search for services that are not listed, the discovery fails and emits networkServiceDiscoveryFailed(). Example:

 <key>NSLocalNetworkUsageDescription</key>
 <string>Uses Bonjour to discover local network services.</string>
 <key>NSBonjourServices</key>
 <array>
     <string>_dns-sd._udp.</string>
     <string>_http._tcp.</string>
     <string>_http._udp.</string>
     <string>_companion-link._tcp.</string>
     <string>_mi-connect._udp.</string>
 </array>

Android Integration

No additional steps are required on Android.

macOS Integration

No additional steps are required on macOS.

Property Documentation

Signal Documentation

 {
   "NSNetServicesErrorCode": -72004,
   "NSNetServicesErrorDomain": 10
 }

Method Documentation

 ZeroConf.startNetworkServiceDiscovery("_companion_link._tcp.", "local")

 {
   "addresses": [
     "169.254.1.2",
     "fe80::424:abcd:1234:4628",
     "169.254.3.4",
     "fe80::18a1:abcd:1234:a81c"
   ],
   "attributes": {
     "rpAD": "8aa16bddcd51",
     "rpBA": "AB:CD:12:5E:8D:5D",
     "rpFl": "0x20000",
     "rpHN": "abcdefa1b11e",
     "rpMac": "0",
     "rpVr": "360.4"
   },
   "domain": "local.",
   "hostName": "My-Mac.local.",
   "name": "My Mac",
   "port": 12345,
   "resolved": true,
   "type": "_companion-link._tcp."
 }

 {
   "domain": ".",
   "errorData": {
     "NSNetServicesErrorCode": -72004,
     "NSNetServicesErrorDomain": 10
   },
   "name": "_remoted",
   "resolved": false,
   "type": "_tcp.local."
 }